#include "alltbtex.pov"
#include "sprock.pov"

#include "RMCRing.pov"                

#declare MyChrome = texture {NotAsShinyTex}     
             
                                                
                        
#declare NutSide=0;   
#declare HalfNutSize=.6;                                    

#declare CrankNut3=difference{union{cylinder{0, .075*y,.75}
                                    sphere{<0,.13,0>,.42 scale <.96,.29,.96>}    //close union! of the "puff" top !  
                                   
                                    }  //end union
                              box{<-1,0,-1><1,-1,1>} //cut off below "lip" sphere first...      
                              #while (NutSide<12)    
                                box{<-.2,-.01,-.2> <.2,.101,.2> translate x*HalfNutSize rotate y*30*NutSide } //biting off a 12th of the disk/cylinder
                                 box{<-.03,-.03,-.07> <.03,.03,.07> 
                                        rotate z*45
                                        translate <HalfNutSize*.73,.075,0> rotate y*(30*NutSide-15)
                                        //texture{ShinyTex} 
                                         } 
                                #declare NutSide=NutSide+1;
                              #end  //while loop  
                              cylinder{ -5*y, 5*y, .33}  //the nuthole  
                              
                               
                              }  //close diff               
                               
                  
                  

#declare Cranx=difference{union{object{RMCRing rotate z*90 translate<23,-2,11.5>}  
                                cone{<23,1.75,11.5>,.33,<23,1.6,11.5>,.37}        //threaded blurmp...
                                cylinder{<23,1.475,11.5>,<23,1.375,11.5>,.86}            //dust cover
                                cylinder{<23,1.55,11.5>,<23,1.475,11.5>,.82}         //and a washer, kinda big?
                                cylinder{<23,1.55,11.5>,<23,1.60,11.5>,.56}           //and the  washer under the nut... 
                                object{CrankNut3 translate <23,1.60,11.5>}
                                cylinder{<23,-2,11.5>,<18,-3,16.5>,.37 } 
                                sphere { <18,-3,16.5>, 0.33 }  // end of sphere   
                                sphere { <23,-2,11.5>, 0.33 }   
                                sphere { <23,2,11.5>, 0.33 }
                                cylinder {<23,2,11.5>,<28,3,6>,.33}            // and cranx   
                                sphere { <28,3,6>, 0.33 }                              // now with ballsy ends!!     
                                cylinder {<23,2,11.5>,<23,-2,11.5>,.33}  //bottom bracket (Ashtabula style!)   
                                 } //end big Ashtabula chrome-hunk... 
                           cylinder {<28,3.4,6>,<28,1.9,6>,.17}          //pedal hole R
                           cylinder {<18,-3.4,16.5>,<18,-1.9,16.5>,.17}    //pedal hole L    
                           }  //end diff...