// Persistence of Vision Ray Tracer Scene Description File
// File: decocand.pov
// Vers: 3.1 Superpatch
// Desc: A decorative candle ("Norwegian" Type)
// Date: 99_11_04
// Auth: ReVerSi (reinhard.rettelbach.KH@t-online.de)



// ==== Standard POV-Ray Includes ====
#include "colors.inc"	// Standard Color definitions
#include "textures.inc"	// Standard Texture definitions
#include "skies.inc"
 
global_settings {max_trace_level 70}

#declare camera_location = <0, 5, -10>;
#declare camera_look_at = <0, 0, 0>;


camera
{
  location  camera_location
  look_at   camera_look_at
}

// create a regular point light source
light_source
{
  0*x // light's position (translated below)
  color red 1.0  green 1.0  blue 1.0  // light's color
  translate camera_location + <-2, 3, -1>
}   
light_source
{
  1.8*x // light's position (translated below)
  color red 1.0  green 0  blue 0  // light's color 
  //translate <200, 100, -200>
}    
background {rgb <0.2, 0.2, 0.6>}     


plane {y, -3 pigment {checker color rgb <0.9, 0.9, 1> color rgb <0.95, 0.85, 0.15> rotate 30*y}}

//*************************************
//the white, opaque wax on the outside*
//*************************************  
#declare F1 = function {pigment {crackle form <-1.1, 1.2, -0.3>
				 color_map{
				[0.07 rgb 0]
				[0.07 rgb 1]}
				} 
			}
difference{			
	isosurface{ function{(x^2+z^2-0.7) + (0.3*(F1(4*x, 5*y, 4*z)) + 0.05*noise3d(6.5*x, 6.5*y, 6.5*z))} 
		  threshold 0.3
		  accuracy 0.00002
		  scale 3 rotate<0, 90, 0>}
	cylinder{<0, -3.1, 0>, <0, 3.1, 0>, 2.8}
		  texture{
		  pigment {rgb <1, 1, 1>}
		  normal {bumps 0.15 scale 0.05}
		  finish{ ambient 0.55 specular 0.1 roughness 0.3}
		  }
	  }	  
//**********************************
//the inner, red wax****************
//**********************************	  
cylinder{<0, -2.9, 0>, <0, 2.85, 0>, 2.81   hollow
	 	 texture{pigment {rgbf <1, 0, 0, 0.65>}} 
	         interior {media {emission rgb <0.1, 0, 0>}
	         	   media {scattering{1, 1} density{ gradient y density_map{
	         	   				   [0 rgb 0.7]
	         	   				   [0.75 rgb 0]               }
	         	   				   scale <1, 6, 1> translate <0, 3, 0>
	         	   				   }
	 		  	   } 
	 	           }
	 }
	 

cylinder{<0, -0.07, 0>, <0, 0.07, 0>, 1
	 pigment {wood sine_wave color_map{
	 		[0 rgbf <1, 0.4, 0.4, 1>]
	 		[0.65 rgbf <1, 0, 0, 0.5>]
	 			}                    
	 	rotate <90, 0, 0>}
	 scale <2.81, 1, 2.81> translate <0, 2.91, 0>
	 }
	 
//************************************
//Der Docht***************************
//************************************
	 
sphere_sweep{ b_spline_sphere_sweep, 7
	<0, -3, 0>, 0.12
	<0, -1, 0>, 0.12
	<0, 0, 0>, 0.12
	<0, 0.5, 0>, 0.12
	<0.12, 0.8, 0>, 0.12
	<0.23, 0.9, 0.05>, 0.12
	<0.45, 1, 0.1>, 0.12
	pigment{gradient y color_map{
		[0.6 rgb <1, 1, 1>]
		[0.7 rgb <0.4, 0.3, 0.05>]
		[0.75 rgb <0, 0, 0>]}
		}
	scale <1, 0.5, 1> translate<0, 3, 0>
	}
	
//***************************************
//and last but not least: a simple flame* 
//***************************************


difference{
	sphere{0, 0.5}
	sphere{<0, -0.3, 0>, 0.35} 
	hollow
	pigment{ rgbt 1}
	interior{ media{ emission rgbf <3, 1.85, 0.1, 0.2>
			 density{ cylindrical color_map{
			 	  [0.3 rgb 1]
			 	  [1 rgb <0.2, 0.2, 4>]}
			 	  turbulence 0.15}
			 	  }
			 }
	scale<.7, 2.5, .7>
	translate <0, 3.9, 0>}